freshmeat headline http://freshmeat.net

how to load: you must be using mIRC 5.8 in order to make the addon works. unzip the addon to any folder you like, then type:

/load -rs freshmeat.mrc

if you unzipped it into c:\something\, and that is not your mirc folder, type:

/load -rs c:\something\freshmeat.mrc

after that, press [YES] on any initialization warning. to use the addon, simply type this in your editbox:

/freshmeat

then it will connect to freshmeat.net, gets the headlines, and popup a dialog :)

credits: all credits go to freshmeat.net, im making this for fun, so i don't think i deserve any :)

any problem, look for me - HaNtU]uU[ @ dalnet. have fun.

; ----------------------
; ø freshmeat headlines
; ø by hantu
; ø http://freshmeat.net
; ----------------------
; ø note: im not related to freshmeat.net
; ----------------------

; ## aliases ##
alias freshmeat {
  secho ** freshmeat headlines: connecting.. please wait :)
  sockopen freshmeat freshmeat.net 80
  if ($hget(freshmeat)) { hfree freshmeat }
  hmake freshmeat 10
}
alias -l secho { echo -a �2,0�*�� $1- }
alias -l _fm {
  if ($1) {
    hadd freshmeat map $1
    if ($dialog(fm) == $null) { dialog -m fm fm }
    did -ra fm 5 $gettok($hget(freshmeat,$1),1,1)
    did -ra fm 3 $gettok($hget(freshmeat,$1),3,1)
    did -ra fm 7 $replace($gettok($hget(freshmeat,$1),2,1),$fmhost,...)
  }
}
alias -l fmhost { return http://freshmeat.net }
alias -l _did.7 { run [ [ $fmhost ] $+ [ $right($did(fm,7).text,-3) ] ] }
alias -l _did.8 { run http://freshmeat.net }
alias -l _did.9 { var %i = $calc($hget(freshmeat,map) - 1) | _fm %i | did -e fm 10 | if (%i == 1) { did -b fm 9 } }
alias -l _did.10 { var %i = $calc($hget(freshmeat,map) + 1) | _fm %i | did -e fm 9 | if (%i == $calc($hget(freshmeat,0).item - 1)) { did -b fm 10 } }
alias -l _did.11 { _fm 1 | did -e fm 10 | did -b fm 9 }
alias -l _did.12 {
  if ($did(fm,12).state == 1) {
    var %i = 50
    while (%i <= 90) {
      dialog -sbr fm -1 -1 147 %i
      inc %i
    }
    did -a fm 13 freshmeat maintains the largest index of Linux software on the Web. $crlf
    did -a fm 13 ---- $crlf
    did -a fm 13 The first stop for Linux users hunting for the software they need for work or play, freshmeat is continuously updated with the latest news from the "release early, release often" community. $crlf
    did -a fm 13 ---- $crlf
    did -a fm 13 In addition to providing news on new releases, freshmeat offers a variety of original content on technical, political, and social aspects of software and programming, written by both freshmeat readers and Free Software luminaries. $crlf
    did -a fm 13 ---- $crlf
    did -a fm 13 The comment board attached to each article serves as a home for spirited discussion, bug reports, and technical support.
  }
  else {
    var %i = 90
    while (%i != 37) {
      dialog -sbr fm -1 -1 147 %i
      dec %i
    }
  }
}

; ## remotes ##
on *:load: {
  if ($version < 5.8) {
  secho freshmeat headlines is made for mIRC 5.8, you are using $version $+ , please download mIRC 5.8 at www.mirc.co.uk
  .unload -rs $script
  }
  else {
    secho freshmeat headlines loaded.. type �/freshmeat� to check headlines at freshmeat.net :)
  }
}
on *:sockopen:freshmeat: {
  sockwrite -n $sockname GET /backend/recentnews.txt
}
on *:sockread:freshmeat: {
  var %t, %i = 1
  if ($sockerr) { dialog -x fm | secho ** freshmeat headlines: error connecting | return }
  :s
  sockread %t
  if ($sockbr) {
    tokenize 32 %t
    if (http://* !iswm $1) && ($time(mmmm) != $1) { sockmark freshmeat $calc($sock($sockname).mark + 1) }
    hadd freshmeat $sock($sockname).mark $instok($hget(freshmeat,$sock($sockname).mark),$1-,$numtok($hget(freshmeat,$sock($sockname).mark),1),1)
    goto s
  }
}
on *:sockclose:freshmeat: { _fm 1 }
on *:dialog:fm:*:*: {
  if ($devent == sclick) {
    if ($did == 7) { _did.7 }
    if ($did == 8) { _did.8 }
    if ($did == 9) { _did.9 }
    if ($did == 10) { _did.10 }
    if ($did == 11) { _did.11 }
    if ($did == 12) { _did.12 }
  }
}

; ## dialog table ##
dialog fm {
  title "FreshMeat.Net Headlines"
  size -1 -1 150 50
  option dbu
  button "", 500, 1, 0 0 0 0, ok
  box "", 1, 1 -2 148 40
  text "News >>", 2, 4 4 25 10
  edit "", 3, 30 3 117 10, read
  text "Date >>", 4, 4 15 25 10
  edit "", 5, 30 14 117 10, read
  text "URL >>", 6, 4 26 25 10
  link "", 7, 30 26 220 15
  link "http://freshmeat.net", 8, 3 41 100 15
  button "<", 9, 57 40 15 10, disable
  button ">", 10, 73 40 15 10
  button "Refresh", 11, 89 40 30 10
  check "About", 12, 119 40 30 10, push
  edit "", 13, 1 52 148 50, read vsbar multi
}