Introduction

Dalnet Private Flood Protection by SeeknDestroy

This script protects against ALL types of private IRC floods :

Query, Notice, Invite, CTCP, and DCC Send/Chat/Fserve thru IRC Server & IP

The same settings apply to all of them. 5 in 5 seconds.

How to Load

1) In mIRC, Type alt+R - this brings you to the Remote Script Editor... if you see text in the white box, go to the File Menu, choose New

2) Copy and paste the code below into the Script Editor

3) Go to the File Menu, choose Save As, pick a name for the script, Save it

4) That's it - there are no settings required

Code

on *:connect:{
  if ($hget(flood,reconnect.protect)) {
    echo -as You were flooded offline.  Silence will be turned on in 5 seconds.
    echo -as You will need to type /silence -*� to turn it off when you feel it is safe.
    .timersilence 1 5 silence +*
  }
}

on ^1:notice:*:?:{
  if (!$istok(chanserv nickserv memoserv,$nick,32)) {
    hinc -mu5 flood notice 1
    if ($hget(flood,notice) == 5) { flood.silence Notice }
    elseif ($hget(flood,notice) > 5) { halt }
  }
}

on ^1:invite:#:{
  hinc -mu5 flood invite 1
  if ($hget(flood,invite) == 5) { flood.silence Invite }
  elseif ($hget(flood,invite) > 5) { halt }
}

on ^1:open:?:*:{
  hinc -mu5 flood query 1
  if ($hget(flood,query) == 5) { flood.silence Query | close -m }
  elseif ($hget(flood,query) > 5) { halt }
}

on ^1:open:=:{
  hinc -mu5 flood chat 1
  if ($hget(flood,chat) == 5) { flood.silence DCC Chat }
  elseif ($hget(flood,chat) > 5) { halt }
}

on ^1:open:!:{
  hinc -mu5 flood fserve 1
  if ($hget(flood,fserve) == 5) { flood.silence DCC Fserve }
  elseif ($hget(flood,fserve) > 5) { halt }
}

ctcp ^1:send:?:{
  hinc -mu5 flood send 1
  if ($hget(flood,send) == 5) { flood.silence DCC Send }
  elseif ($hget(flood,send) > 5) { halt }
}

ctcp ^1:*:?:{
  hinc -mu5 flood ctcp 1
  if ($hget(flood,ctcp) == 5) { flood.silence CTCP }
  elseif ($hget(flood,ctcp) > 5) { halt }
}

on 1:dccserver:chat:{
  hinc -mu5 flood dcc.chat 1
  if ($hget(flood,dcc.chat) == 5) { flood.dcc Chat }
}

on 1:dccserver:send:{
  hinc -mu5 flood dcc.send 1
  if ($hget(flood,dcc.send) == 5) { flood.dcc Send }
}

on 1:dccserver:fserve:{
  hinc -mu5 flood dcc.fserve 1
  if ($hget(flood,dcc.fserve) == 5) { flood.dcc Fserve }
}

alias flood.silence {
  silence +* | .timerunsilence 1 180 silence -*
  echo -as $1- Flood Detected.  Silencing for 3 minutes.
  hadd -mu60 flood reconnect.protect 1
}

alias flood.dcc {
  dccserver off | .timerdccon 1 180 dccserver on
  echo -as DCC (via IP) $1 Flood Detected.  Disabling DCC for 3 minutes.
}